Примеры функций И ИЛИ в Excel для записи логических выражений

Функция И в Excel принимает одно или несколько логических выражений и возвращает логическое значение, которое зависит от результата вычислений всех этих выражений. Если результат вычисления каждого выражения – значение ИСТИНА, функция И вернет истинное значение. Если результатом вычисления хотя бы одного из выражений является значение ЛОЖЬ, функция И вернет логическое ЛОЖЬ.

Функция ИЛИ выполняет проверку логических выражений, принятых в качестве аргументов, и возвращает значение ИСТИНА, если результат выполнения хотя бы одного из этих выражений является истинным.

Примеры использования функций И ИЛИ в логических выражениях Excel

Пример 1. В учебном заведении для принятия решения о выплате студенту стипендии используют два критерия:

  1. Средний балл должен быть выше 4,0.
  2. Минимальная оценка за профильный предмет – 4 балла.

Определить студентов, которым будет начислена стипендия.

Исходная таблица:

Пример 1.

Для решения используем следующую формулу:

используем формулу.

=И(E2>=4;СРЗНАЧ(B2:E2)>=4)

Описание аргументов:

  • E2>=4 – проверка условия «является ли оценка за профильный предмет не менее 4 баллов?»;
  • СРЗНАЧ(B2:E2)>=4 – проверка условия «является ли среднее арифметическое равным или более 4?».

Запишем аналогичные формулы в остальных ячейках. В результате получим:

В результате.

Как видно выше на рисунке студенты под номером: 2, 5, 7 и 8 - не получат стипендию.



Формула с логическим выражением для поиска истинного значения

Пример 2. На предприятии начисляют премии тем работникам, которые проработали свыше 160 часов за 4 рабочих недели (задерживались на работе сверх нормы) или выходили на работу в выходные дни. Определить работников, которые будут премированы.

Исходные данные:

Пример 2.

Формула для расчета:

ИЛИ.

=ИЛИ(B3>160;C3=ИСТИНА())

Описание аргументов:

  • B3>160 – условие проверки количества отработанных часов;
  • C3=ИСТИНА() – условие проверки наличия часов работы в выходные дни.

Используя аналогичную формулу проведем вычисления для всех работников. Полученный результат:

Полученный результат.

То есть, оба условия возвращают значения ЛОЖЬ только в 4 случаях.

Формула с использованием логических функций ИЛИ И ЕСЛИ

Пример 3. В интернет-магазине выполнена сортировка ПК по категориям «игровой» и «офисный». Чтобы компьютер попал в категорию «игровой», он должен соответствовать следующим критериям:

  1. CPU с 4 ядрами или таковой частотой не менее 3,7 ГГц;
  2. ОЗУ – не менее 16 Гб
  3. Видеоадаптер 512-бит или с объемом памяти не менее 2 Гб

Распределить имеющиеся ПК по категориям.

Исходные денные:

Пример 3.

Для определения категории используем следующую формулу:

ЕСЛИ.

Описание аргументов:

И(ИЛИ(B3>=4;C3>=3,7);D3>=16;ИЛИ(E3>=2;F3>=512)) – функция И, проверяющая 3 условия:

  1. Если число ядер CPU больше или равно 4 или тактовая частота больше или равна 3,7, результат вычисления ИЛИ(B3>=4;C3>=3,7) будет значение истинное значение;
  2. Если объем ОЗУ больше или равен 16, результат вычисления D3>=16 – ИСТИНА;
  3. Если объем памяти видеоадаптера больше или равен 2 или его разрядность больше или равна 512 – ИСТИНА.

«Игровой» - значение, если функция И возвращает истинное значение;

«Офисный» - значение, если результат вычислений И – ЛОЖЬ.

Этапы вычислений для ПК1:

  1. =ЕСЛИ(И(ИЛИ(ИСТИНА;ИСТИНА);ЛОЖЬ;ИЛИ(ЛОЖЬ;ЛОЖЬ));"Игровой";"Офисный")
  2. =ЕСЛИ(И(ИСТИНА;ЛОЖЬ;ЛОЖЬ);"Игровой";"Офисный")
  3. =ЕСЛИ(ЛОЖЬ;"Игровой";"Офисный")
  4. Возвращаемое значение – «Офисный»

Результаты расчетов для всех ПК:

Результаты расчетов.

Особенности использования функций И, ИЛИ в Excel

Функция И имеет следующую синтаксическую запись:

=И(логическое_значение1;[логическое_значение2];…)

Функция ИЛИ имеет следующую синтаксическую запись:

=ИЛИ(логическое_значение1;[логическое_значение2];…)

Описание аргументов обеих функций:

  • логическое_значение1 – обязательный аргумент, характеризующий первое проверяемое логическое условие;
  • [логическое_значение2] – необязательный второй аргумент, характеризующий второе (и последующие) условие проверки.

Сравнения результатов, возвращаемых функциями И, ИЛИ в однотипных ситуациях:

Сравнения результатов.

Примечания 1:

  1. Аргументами должны являться выражения, результатами вычислениями которых являются логические значения.
  2. Результатом вычислений функций И/ИЛИ является код ошибки #ЗНАЧ!, если в качестве аргументов были переданы выражения, не возвращающие в результате вычислений числовые значения 1, 0, а также логические ИСТИНА, ЛОЖЬ.

Примечания 2:

  1. Функция И чаще всего используется для расширения возможностей других логических функций (например, ЕСЛИ). В данном случае функция И позволяет выполнять проверку сразу нескольких условий.
  2. Функция И может быть использована в качестве формулы массива. Для проверки вектора данных на единственное условие необходимо выбрать требуемое количество пустых ячеек, ввести функцию И, в качестве аргумента передать диапазон ячеек и указать условие проверки (например, =И(A1:A10>=0)) и использовать комбинацию Ctrl+Shift+Enter. Также может быть организовано попарное сравнение (например, =И(A1:A10>B1:B10)).
  3. Как известно, логическое ИСТИНА соответствует числовому значению 1, а ЛОЖЬ – 0. Исходя из этих свойств выражения =(5>2)*(2>7) и =И(5>2;2>7) эквивалентны (Excel автоматически выполняет преобразование логических значений к числовому виду данных). Например, рассмотрим этапы вычислений при использовании данного выражения в записи =ЕСЛИ((5>2)*(2>7);”true”;”false”):
  • =ЕСЛИ((ИСТИНА)*(ЛОЖЬ);”true”;”false”);
  • =ЕСЛИ(1*0;”true”;”false”);
  • =ЕСЛИ(0;”true”;”false”);
  • =ЕСЛИ(ЛОЖЬ;”true”;”false”);
  • Возвращен результат ”false”.

Примечания 3:

  1. Функция ИЛИ чаще всего используется для расширения возможностей других функций.
  2. В отличие от функции И, функция или эквивалентна операции сложения. Например, записи =ИЛИ(10=2;5>0) и =(10=2)+(5>0) вернут значение ИСТИНА и 1 соответственно, при этом значение 1 может быть интерпретировано как логическое ИСТИНА.
  3. Подобно функции И, функция ИЛИ может быть использована как формула массива для множественной проверки условий.

en ru